ПРИМЕРЫ ПРАКТИЧЕСКИХ ЗАДАЧ




Рассмотрим ряд примеров, разбор которых позволит читателю освоить основные средства Excel. Кроме того, читатель, возможно, обнаружит среди предложенных примеров задачу, похожую на ту, что он решает ежедневно на своем рабочем месте, но делает это вручную. Представленный ниже материал не следует воспринимать как пособие по финансовой математике. Тематика предлагаемых задач часто связана с денежными расчетами просто потому, что их постановка понятна любому читателю. Это, конечно, совершенно не означает, что для такого инструмента не найдется множества технических приложений. Отметим, что некоторые задания могут быть исполнены несколькими, иногда, возможно, и более эффективными, способами. Цель предлагаемого далее материала – не получение самого лучшего решения в каждом конкретном случае, а овладение техникой построения и оформления таблиц.

Замечания. 1. Информация, используемая в примерах, носит условный характер и не отражает реального законодательства. 2. Таблицы представлены на рисунках как в нормальном (“результативном”) виде, так и, по возможности, – в формульном виде. Номера рисунков в тексте совпадают с номерами задач. 3. Следует иметь в виду, что данные во многих примерах сопровождаются единицами измерения ($, кг, шт и др.), которые не вводятся непосредственно в клетки таблицы, но устанавливаются с помощью форматирования.

@ В связи с тем, что во многих примерах имеются “процентные” данные, напомним, как их использовать. Проценты вводятся в таблицу как десятичные коэффициенты, которым затем придается формат %, либо они сразу вводятся со знаком процента. В Excel число, изображенное со знаком процента, соответствует в сто раз меньшей величине без знака %. То, что, например, выглядит как 20%, на самом деле является 0,2, то, что выглядит как 100%, соответствует 1. Иными словами, это просто разные формы представления одного и того же числа.

Пусть нам нужно выделить часть числа, определенную как его некоторый процент. При вычислениях “на бумаге” следует выполнить такие действия

искомая_часть_числа=исходное_число * процент_от_числа/100%.

В Excel же достаточно формулы вида искомая_часть_числа=исходное_число * процент_от_ числа.

Т.е. нужно умножить это число на процент. Делить на 100% нет необходимости. Однако, если это сделать, результат не измениться ведь здесь 100%º1.

Например, нужно найти 20% от числа 500: =500*20%=500*0,2=100.

Обе формулы в Excel совершено идентичны.

Другая ситуация. Пусть нужно вычислить новое значение числа, уменьшенное на некоторый процент (например, учесть скидку). Здесь следует записать так

новое_число=исходное_число – исходное_число * процент или короче

новое_число=исходное_число * (1–процент).

Например, пусть старая цена товара составляет 500 руб., а новая цена имеет скидку в 20%. Определить новую цену товара в рублях =500(1–20%)=500(100%–20%)=500(1–0,2). Все три записи в Excel идентичны.

Аналогичным образом вычисляется наценка: новое_число=исходное_число * (1+процент).

Наценка в 20% к 500 руб. даст такую новую цену =500(1+20%)=500(100%+20%)=500(1+0,2).

Поскольку, обычно, такие данные участвуют в формулах не в качестве констант, а своими адресами (например, А3 и В4), вполне очевидны формулы вида =А3*(1–В4) и =А3*(1+В4) для скидки и наценки. Очевидно также, что превратить одну функцию в другую можно просто изменив знак непосредственно при числе, находящемся в ячейке, содержащей процент (здесь в В4). Во всех случаях следует иметь в виду, что нельзя складывать (вычитать) процент с каким-либо иным значением, кроме процента (коэффициента).

Замечание. Владельцы калькуляторов знают, что (при наличии на нем кнопки %) правомочно действие, в котором с собственно данными (например с деньгами) складываются/вычитаются проценты. Например, действие вида 200р+10% повлечет результат равный 220р (т.е. будет начислен желаемый процент), что, как будто, противоречит вышесказанному. Здесь следует учесть, что в калькуляторе имеется специальная операция взятия процента, которая на сам деле выполнила действие вида 200+200*10%/100%. Поскольку в Excel отсутствует подобный механизм начисления процента, мы должны пользоваться известными школьными правилами работы с процентами.

«««

В начале рассмотрим простенький пример, который нам поможет выработать подход к проектированию таблиц. На рис. 5.0а слева изображена вся таблица, справа – формулы для столбца D. Пусть требуется выполнить расчет платы за квартиру. Положим она состоит из оплаты за коммунальные услуги (по 2 руб. за квадратный метр площади) и оплаты за газоснабжение (по 3 руб. с каждого проживающего в квартире человека).

Здесь реализован очевидный механизм расчета

квартплата=площадь * тариф_за_коммунальные_услуги + человек * тариф_за_газ.

Или в виде чисел для первой квартиры D3=80*2+4*3.

  A B C D   D
  РАСЧЕТ КВАРТПЛАТЫ    
  Квартира Площадь Человек Кв. плата   Кв. плата
  №1         =B3*2+C3*3
  №2         =B4*2+C4*3
  №3         =B5*2+C5*3
  №4         =B6*2+C6*3
  ВСЕГО         =СУММ(D3:D6)
      Рис. 5.0а      
               

Поскольку квартир в доме может быть очень много, непосредственный ввод таких формул для каждой из них делает использование компьютера малопродуктивным, если не сказать бессмысленным. По существу, мы применяем его как тривиальный калькулятор. Конечно, этого и не требуется. Нужно использовать не арифметическое, а алгебраическое представление данных, когда они участвуют в формуле не своими непосредственными значениями, а адресами ячеек (т.е. переменными), в которых они находятся. В нашем случае D3=B3*2+ C3*3. Далее следует просто скопировать (воспользовавшись маркером заполнения клетки) первую формулу D3=B3*2+C3*3 во все нижележащие ячейки. В следующей снизу клетке она превратится в D4=B4*2+C4*3, затем в D5=B5*2+C5*3 и т.д. Здесь проявилось чрезвычайно полезное свойство копируемых ссылок – адаптируемость адресных ссылок под новое положение.

  A B C D   D
  Тарифы оплаты    
  комм/уc: 2,0р/метр газ: 3,0р/чел   3,0р/чел
  РАСЧЕТ КВАРТПЛАТЫ    
  Квартира Площадь Человек Кв. плата   Кв. плата
  №1 80м   172,0р   =B5*B$2+C5*D$2
  №2 60м   129,0р   =B6*B$2+C6*D$2
  №3 110м   235,0р   =B7*B$2+C7*D$2
  №4 120м   264,0р   =B8*B$2+C8*D$2
  ВСЕГО 370м   800,0р   =СУММ(D5:D8)
      Рис. 5.0б      

Очевидным недостатком нашего решения является его зависимость от изменения тарифов – при их пересмотре придется изменять множество формул. В виду этого, в электронных таблицах все нормативные данные выносят в отдельные области листа (или даже на отдельные листы), обычно, в верхней его части. В нашем случае такими данными являются цены на коммунальное услуги и газ. Разместим их в клетках В2 и D2 (рис. 5.0б), а в формулах вместо констант (2 руб. и 3 руб.) укажем ссылки на эти ячейки. Как и ранее, введем формулу только для первой квартиры (D5=B5*B2+C5*D2), скопировав затем ее вниз. Если поступить таким образом, мы обнаружим что в нижележащих клетках D6, D7 и т.п. получены выражения вида:

D5=B5*B2+C5*D2

D6=B6* B3 +C6* D3,

D7=B7* B4 +C6* D4 и т.д.

Они неверны (ошибочные значения подчеркнуты). Поскольку при перемещении вниз изменились также адреса, содержащие тарифы, то площадь квартиры №2 перемножается уже не на тариф коммунальных услуг из ячейки В2, а на содержимое пустой клетки В3. Аналогично с оплатой за газ. Это же относится и ко всем другим квартирам. Чтобы избежать нежелательного изменения адресов тарифов, они фиксируются в формулах (“замо­раживаются”) введением знака $ перед номером строки (D5=B5*B$2+C5* D$2). Копирование такой формулы вниз

  A B   B
  Вклад:      
  ПРОСТЫЕ ПРОЦЕНТЫ    
  Норма Прибыль   Прибыль
  10% 100,00   =A4*$B$1
  15% 150,00   =A5*$B$1
  20% 200,00   =A6*$B$1
  30% 300,00   =A7*$B$1
    750,00   =СУММ(B4:B7)
    Рис. 5.1    

D5=B5*B$2+C5*D$2

D6=B6*B$2+C6*D$2,

D7=B7*B$2+C6*D$2 и т.д.

уже не повлечет изменения цифры 2 в адресах B$2 и D$2 (результаты изображены на рис. 5.0б).

 

 

Ранее нами уже обсуждался вопрос о возможности вставки строк в таблицу и влияние этого действия на поведение итоговых функции. В нашем случае вставка новых данных (новых квартир) между 4-ой и 5-ой и между 8-ой и 9-ой строками будет проигнорирована функцией СУММ(D5:D8). Обеспечить правильную реакцию функции на верхнюю вставку можно, включив заголовок таблицы в область суммирования, т.е. сделать D9=СУММ(D4:D8). Правильную реакцию на дополнение таблицы в нижней ее части можно реализовать (начиная с версии Excel-2000), если установить флажок Расширять форматы и формулы в списках (вкладка Правка). Однако, если (конечно, в сложных случаях) этот механизм не срабатывает, такое дополнение можно осуществлять оставляя пустой самую последнюю (в нашем случае девятую) строку между собственно данными и десятой строкой, где теперь будут вычисляться суммы. Тогда щелчок мышью на строке 9 с последующей вставкой новой строки опустит 9-ю и 10-ю строки ниже и изменит в последней формулу на D11= СУММ(D4:D10), что соответствует нашим целям.

Исключить необходимость присутствия пустой строки среди данных можно, если воспользоваться более сложной функцией суммирования (см. вставку @ после раздела 4.16 в главе “Функции рабочего листа”) вида D9= СУММ(D$4:ИНДЕКС(D:D;СТРОКА()–1)), а если вы хотите изъять заголовок таблицы из области суммирования, то

D9=СУММ(ИНДЕКС(D:D;5):ИНДЕКС(D:D;СТРОКА()–1)).

Теперь допускается вставка новых строк в произвольное место таблицы (например, выделив любую строку и нажав Ctrl+Плюс) не заботясь о правильности осуществления суммирования – оно будет корректным.

Больше этого вопроса мы касаться пока не будем и, чтобы не загромождать таблицы, ограничимся применением самой простой функции СУММ(), полагая, что на практике пользователь самостоятельно выберет и применит удобное ему решение.

К оформлению таблицы. Для удобства восприятия информации данные снабжены символами, указывающими на единицы измерения. Так клетка В2 имеет пользовательский формат 0,0”р/метр”, клетка D2 – 0,0”р/чел”, клетки В5-В9 – 0”м”, клетки D5-D9 – 0,0”р”.

Пример 5.1. Расчеты по вкладам. Построить таблицу вычисления прибыли от инвестирования суммы, равной 1000 (клетка В1), на четыре года в некоторое производство или в банк. Предполагаемая, выплачиваемая ежегодно, норма прибыли должна составить 10%, 15%, 20% и 30% соответственно. Таблица в числовом и формульном (только для столбца В) видах приведена на рис. 5.1. Используемые табличные функции очевидны и реализуют выражение вида прибыль=вклад*норма. Способ исчисления дохода по вкладу здесь соответствует так называемым простым процентам.

Пример 5.2. Расчеты по вкладам (сложные проценты). Аналогичная задача, но предполагается, что инвестор не изымает прибыль, а реинвестирует ее снова в дело. Такой механизм начисления дохода определяется термином “сложные проценты” или “капитализа­ция дохода”. Здесь:

прибыль=норма*предыдущая_сумма_на_счету сумма=предыдущая_сумма_на_счету + прибыль.

Замечание. В этой задаче копирование формул возможно только со второго года (со строки 5). Именно с этого года формулы начинают повторяться.

Значение нарастающей суммы можно выяснить и с помощью име­ющейся в Excel финансовой функции вычисления будущего значения прибыли с изменяющейся процентной ставкой БЗРАСПИС()

сумма=БЗРАСПИС(вклад; нормы_предшествующих_лет).

Так, полное ее значение по завершении последнего четвертого года составит величину, равную выражению B7=БЗРАСПИС(B1;A4:A7). На рис. 5.2б изображена таблица с решением той же задачи (и, естественно, с теми же результатами), но с использованием указанной функции. Если не требуется знать значения накопленных вкладов в конце каждого года, можно, вообще, ограничиться только одной формулой из последней ячейки =БЗРАСПИС(B$1; A$4:A7). А если не нужна таблица, то и вообще =БЗРАСПИС(1000;{0,1;0,15;0,2;0,3}).

 

 

  A B C   B C   A B
  Вклад:             Вклад:  
  СЛОЖНЫЕ ПРОЦЕНТЫ            
  Норма Прибыль Сумма   Прибыль Сумма   Норма Сумма
  10% 100,0 1100,0   =A4*B1 =B1+B4   10% =БЗРАСПИС(B$1;A$4:A4)
  15% 165,0 1265,0   =A5*C4 =B5+C4   15% =БЗРАСПИС(B$1;A$4:A5)
  20% 253,0 1518,0   =A6*C5 =B6+C5   20% =БЗРАСПИС(B$1;A$4:A6)
  30% 455,4 1973,4   =A7*C6 =B7+C6   30% =БЗРАСПИС(B$1;A$4:A7)
    973,4     =СУММ(B4:B7)        
  Рис. 5.2а   Рис. 5.2б

Пример 5.3. Распределение фонда заработной платы. Создать таблицу распределения фонда заработной платы сотрудников подразделения в соответствии с устанавливаемым руководителем коэффициентом (индивидуальной оценкой качества и ответственности труда). Для определения зарплаты здесь сначала нужно найти “вес” единицы коэффициента в денежном исчислении (т.е. фонд_зарплаты/сумма_коэффициентов), а затем умножить его на индивидуальный коэффициент работника

зарплата_работника=фонд/сумма_коэффициентов*коэффициент_работника.

Отсюда следует, что прежде нужно найти сумму всех коэффициентов В8=СУММ(B4:B7). Тогда зарплата Петра будет вычисляться по формуле C4=B$1/B$8*B4. И, наконец, подсчитывается сумма всех установленных зарплат C8=СУММ(C4:C7). Как видим, она в точности равна фонду зарплаты (1000), т.е. выражения записаны верно. На рис. 5.3а таблица отображена в числовом и в формульном форматах.

 

  A B C   B C
  Фонд:          
  РАСПРЕДЕЛЕНИЕ ЗАРПЛАТЫ      
  Имя Коэфф. Зарплата   Коэфф. Зарплата
  Петр   178,57     =B$1/B$8*B4
  Иван 1,1 196,43   1,1 =B$1/B$8*B5
  Сергей   357,14     =B$1/B$8*B6
  Олег 1,5 267,86   1,5 =B$1/B$8*B7
  ВСЕГО 5,6 1000,00   =СУММ(B4:B7) =СУММ(C4:C7)
      Рис. 5.3а    
  A B C D
  Фонд:      
  РАСПРЕДЕЛЕНИЕ ЗАРПЛАТЫ
  Имя Прежняя зарплата Коэфф. Новая зарплата
  Петр     173,21
  Иван   1,1 210,54
  Сергей     306,43
  Олег   1,5 309,82
  ВСЕГО   5,6 1000,00
    Рис. 5.3б  

Усложним задачу (рис. 5.3б). Пусть задается не только коэффициент, но и минимальная зарплата для каждого сотрудника. Такая ситуация возможна в случае, например, если фонд заработной платы увеличен и прибавку следует распределить среди сотрудников. При этом не должно получиться так, что кто-то станет получать зарплату меньшую, чем раньше. Эти данные находятся в столбце Прежняя зарплата. Отсюда формула зарплаты работника

  A B C D
  Фонд:      
  РАСПРЕДЕЛЕНИЕ ЗАРПЛАТЫ
  Имя Прежняя зарплата Коэфф. Новая зарплата
  Петр     =(B$1–B$8)/C$8*C4+B4
  Иван   1,1 =(B$1–B$8)/C$8*C5+B5
  Сергей     =(B$1–B$8)/C$8*C6+B6
  Олег   1,5 =(B$1–B$8)/C$8*C7+B7
  ВСЕГО =СУММ(B4:B7) =СУММ(C4:C7) =СУММ(D4:D7)
      Рис. 5.3в  

=(фонд–сумма_прежних_зарплат)/сумма_коэффициентов*коэффициент_работника+прежняя_зарплата. Таким образом, здесь делится не весь фонд, а только та его часть, которая больше суммы всех прежних зарплат. Для Петра это D4=(B$1–B$8)/C$8 *C4+B4. Остальные формулы (рис. 5.3в) очевидны. Такое решение подразумевает, что выделенный фонд заработной платы не может быть менее суммы прежних зарплат (т.е. менее прежнего фонда оплаты труда). В случае, если он окажется меньше (у нас меньше 590), результаты будут бессмысленны. Если такое обстоятельство возможно, следует учесть его, например, следующим образом

D4=ЕСЛИ(B$8>=B$1;

(B$1–B$8)/C$8*C4+B4;B$1/C$8*C4).

 

Здесь, если сумма прежних зарплат больше выделенного фонда, вычисления производятся как и ранее, если нет – фонд делится между всеми работниками пропорционально их коэффициентам независимо от прежней зарплаты.

  A B C D E   В C D E
  ПРИЕМ НО ВЫХ АКЦИОН ЕРОВ     ВЫХ АКЦИОН ЕРОВ  
    Сум ма Сум ма   Сум ма Сум ма
  Акционеры старых акций новых акций   старых акций новых акций
    530т.р 100,00% 1230т.р 100,00%   =СУММ (B5:B10 =СУММ (C5:C10) =СУММ (D5:D10) =СУММ (E5:E10)
  Акционер1 100т.р 18,87% 100т.р 8,13%   100т.р =B5/B$4 100т.р =D5/D$4
  Акционер2 150т.р 28,30% 150т.р 12,20%   150т.р =B6/B$4 150т.р =D6/D$4
  Акционер3 200т.р 37,74% 200т.р 16,26%   200т.р =B7/B$4 200т.р =D7/D$4
  Акционер4 80т.р 15,09% 80т.р 6,50%   80т.р =B8/B$4 80т.р =D8/D$4
  Новый акционер1     400т.р 32,52%       400т.р =D9/D$4
  Новый акционер2     300т.р 24,39% Рис. 5.4     300т.р =D10/D$4

Пример 5.4. Перераспределение собственности. Создать таблицу перераспределения собственности акционерного общества при приеме новых пайщиков. Положим, существующие (старые) акционеры имеют голоса (столбец С) в управлении предприятием и распределении прибыли в соответствии со стоимостью их пакетов акций (столбец В). Положим также, что фирма испытывает финансовые затруднения (или хочет расширяться) и ей нужны новые инвесторы, которые готовы внести необходимую для поддержания деятельности компании сумму в 700 тыс. рублей (по 400 и 300 тыс. руб. соответственно). Следует определить новые права каждого из новых и старых пайщиков. Строка 4 в таблице является суммой соответствующих столбцов (например, B4=СУММ(B5:B10)). Относительная значимость каждого акционера определяется по формуле вида C5=B5/B$4 для старого пакета акций и формуле E5=D5/D$4 для нового. Таким образом, новые акционеры получают по 32,52% и 24,39% собственности АО, а относительная собственность старых акционеров соответственно уменьшается. Правильность расчетов подтверждает получение 100% в клетке Е4.

  A B C   C
  ПРИЕМ НОВЫХ АКЦИОНЕРОВ    
  Акционеры 100% 100%   =СУММ(С3:C8)
  Акционер1 20% 14%   =(1–(C$7+C$8))*B3
  Акционер2 25% 18%   =(1–(C$7+C$8))*B4
  Акционер3 20% 14%   =(1–(C$7+C$8))*B5
  Акционер4 35% 25%   =(1–(C$7+C$8))*B6
  Новый акционер1   20%   20%
  Новый акционер2   10% Рис. 5.5 10%

Пример 5.5. Перераспределение собственности (относительное). Схожая задача. Пусть абсолютная рыночная стоимость акций неизвестна, поскольку они не предлагаются на бирже, а покупная их цена с истечением времени (из-за инфляции и изменения состояния предприятия) ни о чем больше не говорит. Вообще, абсолютная стоимость акций до тех пор, пока они не предлагаются к продаже, и не имеет большого значения – важно знать, какая часть собственности кому принадлежит. Положим, новые акционеры вносят какую-то сумму или другие активы при условии, что им будет передано право собственности на 20% и 10% соответственно. Нам надо определить новые индивидуальные права старых собственников, при условии, что их собственность уменьшилась до величины 100%–(20%+10%)=70%. Здесь новые права (клетки С3, С4, С5, С6) старых собственников вычисляются по формуле вида:

новые_права_старых_акционеров=(1–права_новых_акционеров)*старые_права_акционера.

Так для первого акционера С3=(1–(C$7+C$8))*B3. С целью проверки правильности вычислений вверху таблицы все проценты просуммированы (С2=100%).

Пример 5.6. Взаиморасчеты акционеров. Еще одна простая задача из “жизни акционеров”. Положим, для деятельности АО потребовалось срочно внести некоторую сумму (1200 т. руб.), которую и внесли те из акционеров, которые смогли быстро изыскать средства (колонка Внесено ранее). Нам нужно осуществить последующие перерасчеты между акционерами таким образом, чтобы все члены АО внесли суммы пропорциональные частям их собственности (колонка Внесено потом). С этой целью выполним следующие вычисления для каждого из акционеров

=всего_внесено_ранее * его_часть_собственности ­– им_внесено_ранее.

  A B C D E   D E
    ВЗН ОСЫ          
  Ф.И.О. Часть соб- ственности Внесено ранее Внесено потом % взноса   Внесено потом % взноса
  Акционер1 25%   –200 25%   =C$8*B3–C3 =(C3+D3)/C$8
  Акционер2 30%     30%   =C$8*B4–C4 =(C4+D4)/C$8
  Акционер3 20%     20%   =C$8*B5–C5 =(C5+D5)/C$8
  Акционер4 10%     10%   =C$8*B6–C6 =(C6+D6)/C$8
  Акционер5 15%   –420 15%   =C$8*B7–C7 =(C7+D7)/C$8
 
8

ВСЕГО 100%     100% Рис. 5.6 =СУММ(D3:D7) =СУММ(E3:E7)

 

Или в виде формулы для первого акционера: D3=C$8*B3–C3.

  A B C D E F G
  Коэф. оплаты: воскр.:   суббота: 1,5  
  ТАБЕЛЬ И ЗАРПЛАТА
  Дата День недели Петр Иван Олег Всего часов Всего с коэфф.
  10р/ч 8р/ч 6р/ч
  1.окт Вт    
  2.окт Ср 18ч 18ч
  3.окт Чт          
  4.окт Пт 19ч 19ч
  5.окт Сб 10ч   12ч 18ч
  6.окт Вс 22ч 44ч
  7.окт Пн   14ч 14ч
  8.окт Вт   16ч 16ч
  Всего часов: 41ч 45ч 24ч 110ч 138ч
  Часов с коэф.: 51ч 55ч 32ч   138ч
  Зарплата: 510р 440р 192р 1142р  
    Рис. 5.7а дол жно с овпасть

В таблице некоторые значения получились со знаком минус (т.е. акционер, ранее внесший деньги, получит часть их обратно), другие – со знаком плюс (акционер заплатит деньги). Видим, что сумма всех последующих взносов (D8=СУММ(D3:D7)) равна нулю, т.е. наблюдается баланс выплат. Еще раз убедиться в правильности вычислений можно, определив процент окончательных взносов (столбец Е)

=(внесено_сразу+внесено_потом)/внесено_всего.

Или для первого акционера: E3=(C3+D3)/C$8. Видим, что относительные размеры окончательных выплат совпали с размерами относительной собственности каждого из акционеров.

Пример 5.7. Ведение табельной ведомости. Создать таблицу табельной ведомости (документа, фиксирующего число отработанных часов) работников подразделения с расчетом их ежедневной и месячной заработной платы. Считаем, что здесь принята почасовая оплата труда, а рабочий график индивидуальный. Тарифная часовая ставка оплаты установлена своя для каждого работника (ячейки С4, D4, E4). Кроме того, установлена повышенная оплата труда в субботние (с коэффициентом 1,5) и воскресные (с коэффициентом 2) дни. В будний день коэффициент считается равным 1. Пусть, нужно создать таблицу за октябрь месяц. Для быстрого ввода дат месяца воспользуемся механизмом автозаполнения. Внесем в клетку А5 значение 1.окт, а затем мышью скопируем его вниз до конца месяца. Excel расставит нужные последовательные даты месяца автоматически. В столбец День недели введем выражение,

формирующее название дня недели B5= ВЫБОР(ДЕНЬНЕД(A5;2);"Пн";"Вт";"Ср";"Чт";"Пт";"Сб";"Вс"), где номер дня недели (ДЕНЬНЕД(A5;2)) замещается на его имя Пн, Вт и т.д.

В столбце Всего часов определяется сумма астрономических рабочих часов сотрудника (F5=СУММ(C5:E5)) за день, а в столбце Всего с коэффициентом – число часов с учетом увеличивающих коэффициентов за работу в выходные дни (G5=ЕСЛИ(B5="Вс";D$1;ЕСЛИ(B5="Сб";F$1;1))*F5). Таким образом, увеличение оплаты за работу в выходные дни трансформируется в увеличение отработанных часов при их обычной оплате. В итоговой строке 35 введены очевидные формулы суммирования отработанных часов вида С35=СУММ(C5:C34).

В строке 36 – находятся эквивалентные рабочие часы каждого из сотрудников в зависимости от тарифной ставки и работы в выходные

часы_с_коэфф.=общее_число_часов+

воскресных_часов*разность_между_к-том_воскресенья_и_будним_днем+

субботних_часов*разность_между_к-том_субботы_и_будним_днем.

Так, Петром отработано 45 час, а с учетом выходных: 41час+9час(2–1)+2час(1,5–1)=51час.

Или в виде формулы:

C36=C35+СУММЕСЛИ($B5:$B34;"Вс";C5:C34)*($D1–1)+СУММЕСЛИ($B5:$B34;"Сб";C5:C34)*($F1–1).

В строке 37 вычисляется заработок

зарплата=тарифная_ставка * часы_с_коэффициентом.

Отсюда его зарплата (55час*10руб/час=510руб): C37=C$4*C6.

Все Часы с коэфф. для всех работников просуммированы в клетке G36. Видим, что эта сумма (138 час.) совпала с вертикальной суммой, полученной в G35, что показывает правильность расчета эквивалентных часов. Вообще, если имеется какая-либо возможность альтернативного вычисления тех же самых величин, следует это сделать чтобы проверить правильность построения таблицы.

 

  A B C D E F G
  Коэф. оплаты: Воскр.:   Суббота: 1,5  
  ТАБЕЛЬ И ЗАРПЛАТА
  Дата День недели Петр   Олег Всего часов Всего с коэфф.
  10р/ч   6р/ч
  1.окт =ВЫБОР(ДЕНЬНЕД (A5;2);"Пн";"Вт";"Ср";"Чт";"Пт";"Сб";"Вс") 10ч   =СУММ (C5:E5) =ЕСЛИ(B5="Вс"; D$1;ЕСЛИ(B5= "Сб";F$1;1))*F5
               
  8.окт =ВЫБОР(ДЕНЬНЕД (A12;2);"Пн";"Вт";"Ср";"Чт";"Пт";"Сб";"Вс")   =СУММ (C12:E12) =ЕСЛИ(B12="Вс"; D$1;ЕСЛИ(B12= "Сб";F$1;1))*F12
  Всего часов: =СУММ(C5:C34)   =СУММ(E5:E34) =СУММ (F5:F34) =СУММ(G5:G34)
  Часов с коэфф.: =C35+СУММЕСЛИ($B5: $B34;"Вс";C5:C34)*($D1-1) +СУММЕСЛИ($B5:$B34; “Сб”;C5:C34)*($F1-1)   =E35+СУММЕСЛИ($B5: :$B34;"Вс";E5:E34)*($D1-1) +СУММЕСЛИ($B5:$B34; "Сб";E5:E34)*($F1-1)   =СУММ(C36:E36)
  Зарплата: =C36*C$4   =E36*E$4 =СУММ( C37:E37) Рис. 5.7б
                 

 

К оформлению. Для ячеек С4:Е4 установлен пользовательский формат вида 0,0"р/ч", а для колонок F и G – формат [>0]#"ч";#. На рисунке табель показан по текущий день месяца (например, по 8 октября). Остальные пустые пока строки скрыты, с тем, чтобы не отвлекать внимание пользователя.

Пример 5.8. Расчеты с вкладчиками банка. Построить таблицу вычисления годовой премии вкладчику банка. Здесь возможно несколько подходов:

1. Абсолютный размер премии исчисляется исходя из остатка на счету к концу года. Это самый простой и самый несправедливый способ. Если вкладчик 30 декабря снял крупную (или даже всю) сумму со счета, он получит маленькую премию (или не получит ничего) несмотря на то, что банк пользовался его деньгами весь год (пострадает клиент). Наоборот, если сумма была внесена на счет только 30 декабря, вкладчик получит большую премию за один день хранения, несмотря на то, что ранее на счету, возможно, не было ничего (пострадает банк). Учитывая, что в банке много клиентов, такие потери и приобретения банка, вероятнее всего будут взаимно скомпенсированы, однако этого не скажешь об отдельном вкладчике, особенно, если он понесет финансовый ущерб.

2. Премия исчисляется на основе значений остатков (S1, S2, S3, S4) на счету в каждом из четырех кварталов года. Здесь мы исходим из предположения, что в течение всего квартала на счету находилась именно эта величина. Это, конечно, не так, но лучше чем предыдущий подход. Тогда средний годовой остаток вычисляется как сумма всех этих остатков, деленная на число кварталов (S1+S2+S3+S4)/4. На рис. 5.8а искомое значение пропорционально сумме площадей прямоугольников с высотой Si. (закрашены), которую легко вычислить. Назовем поэтому этот метод методом прямоугольников. Ясно, что он имеет значительные погрешности, которые будут уменьшаться с уменьшением элементарных периодов расчета, например, до двух или одного месяцев и меньше.

3. Более точным будет исчисление среднего годового остатка как суммы среднеквартальных остатков (площадь под ломаной линией на рисунке), деленной на четыре.

средний_вклад_за_год=(ср._остаток_1_кв.+ср._остаток_2кв+ср._остаток 3кв+ср._остаток 4кв)/4

или [(S0+S1)/2+(S1+S2)/2+(S2+S3)/2+(S3+S4)/2]/4=[S0+S4+2(S1+S2+S3)]/8.

Назовем этот метод методом трапеций. В таблице на рис. 5.8б сделаны вычисления значения премий методами прямоугольников и трапеций. Для первого вкладчика это следующие формулы

G5=СУММ(C5:F5)/4*D$1, H5=(B5+F5+2*(C5+D5+E5))/8*D$1.

 

  A B C D E F G H   G H
  Проце нт прем ии 10%              
  СЧЕТА КЛИЕНТОВ      
  Номер Начало Остатки по кварталам Премия Премия   Премия Премия
  счета года I II III IV (прямоуг.) (трапеции)   (прямоуг.) (трапеции)
  Счет1           9,0 6,50   =СУММ(C5:F5)/4*D$1 =(B5+F5+2*(C5+D5+E5))/8*D$1
  Счет2           5,5 6,25   =СУММ(C6:F6)/4*D$1 =(B6+F6+2*(C6+D6+E6))/8*D$1
  Счет3           18,8 21,88   =СУММ(C7:F7)/4*D$1 =(B7+F7+2*(C7+D7+E7))/8*D$1
  Сумма           33,3 34,63   =СУММ(G7:G7) =СУММ(H7:H7)

Рис. 5.8б

Заметим, что задача нахождения среднего вклада является задачей вычисления определенно



Поделиться:




Поиск по сайту

©2015-2024 poisk-ru.ru
Все права принадлежать их авторам. Данный сайт не претендует на авторства, а предоставляет бесплатное использование.
Дата создания страницы: 2018-11-17 Нарушение авторских прав и Нарушение персональных данных


Поиск по сайту: